Chapter 2 

[b][i]A long time ago…[/i][/b]

I stare at the rare sweet treat in father's hand, the sight causing saliva to moisten the whole of my mouth. 

"Mother wouldn't want me to eat that," I whisper, partly afraid she'd hear me.

Father grins. "She wants you to eat healthy, that's understandable. But it's just one treat."

I wish it was just about the health part. "She says my teeth will rot away and the Twins will abandon me." She said I would die alone and forgotten, I add in my mind, but can't force the words to leave my lips. 

"She said that?" He frowns. "Why would the Twins care about your teeth?"

I'm not sure. But the thought scares me. She knows the gods better than me. She wouldn't lie about it.

Father pets my head, his touch relaxing my tense frame. "You can decide for yourself. The gods won't care about one treat. I promise."

*fake_choice
    #Take the sweet.
        *set rebel true
        I bite my lip, my gaze glued to the forbidden sweet. If father promises the gods won't abandon me, I suppose it's alright. He knows something about them, too. 
        
        Just to make sure, I raise my gaze to him. His eyes fill me with confidence I need to take it. Quickly I snatch the treat and stuff it in my mouth, as if to make sure mother doesn't see the deed.
        
        The sweetness spreads across my tastebuds, making the lids of my eyes fall shut without my will.
        
        But then, fear takes a grip of my heart. What if the gods will strike me down? With my heart pace quickened I stare at father. He promised nothing wouldn't happen to me.
        
        And indeed, there's no lightning. I check my teeth with my tongue just to be sure. They're still there.
        
        Father frowns at my hesitation. "Didn't you like it?"
        
        I nod, a smile spreading through my face. "I did." And my teeth didn't fall off.
    #I can't take it.
        *set broken true
        My hand twitches.
        
        [i]How do you think that you're fit to worship the gods if you can't even eat what they want you to?[/i]
        
        I yank my wandering hand back. I can't. Even if father promises nothing will happen, I can't take that chance. He's not a druid, he doesn't know what the gods want. 
        
        Mother does. 
        
        And she wouldn't lie about these things.
        
        I shake my head. "I can't."
        
        "It's alright." He smiles and shoves the treat into his own mouth, the sight causing me to bite my lip.

*page_break
[i][b]The late fall[/b][/i]

Freezing wind assaults the naked skin of my face when I open the flimsy excuse of a tent door. The ice rain turned into snow overnight, wrapping the fort into its embrace.

The unforgiving air marks the day I become a full-fledged Roman soldier.

No turning back now.

The marching of the boots passing by litter the otherwise silent Forum, now filled with young semi-barbarians eager to receive their new status as a Roman soldier. Their postures have stiffened during the four months of intensive training, the previous chaotic chatter all but died. Marcus stands in front of us with Niall by his side. They're in full uniform, posing like the statues of the Roman war gods. 

Two ridiculously self-important morons that they are.

Both of them wear their helmet for the occasion, tall and foolish with their feathers and horsehair. Every pair of eyes are on the two men, who bask in the attention.

"First, let me congratulate you on becoming an Auxiliary! I'm honored to have you." Niall shouts. His voice is loud, but it pales in comparison to the next one:

"But your work starts just now. You will be divided into your centuries."

Kegan gawks intently at me every time a tent group is announced their century. It seems they join the ranks of the tenth cohorts or something along those lines. I'm barely interested in the process before Marcus turns to our group.

"Lastly, you lot." He raises his chin and gives us a dirty smile. "You will be a part of the 1st cohort's 1st century."

*page_break

A loud gasp runs through the men. Floyd creases his brows. What is it? How is that important? Floyd leans over to whisper:

"The 1st century is the elite forces of our cohorts combined. They don't usually take in fresh recruits. This is highly unusual."

Oh. I glance at the men throwing death-stares at our group. Kegan's eyes lighten up:

"It means we are the best of the best! Right?" 

Floyd hushes him into silence.

"Do I hear objections?" Marcus shouts and the whispering dies down immediately. There are still a few hostile glances thrown at our contubernium's way.

[i]A bunch of weaklings.[/i]

A voice in my head states.

In my… head.

…The voice is not mine.
*page_break

Kegan almost yelps at the sudden movement as I turn to see if he was the one who spoke. Why didn't your mouth move, I almost ask. But I know it wasn't him.

The voice sighs. [i]Just relax, you little fool—[/i]

Again.

"What in the hells?!" I yelp without thought.

Marcus turns his head with a speed of a predator smelling the day's meal, tens of heads follow his lead to check if someone has lost their mind. Evidently they're not wrong.

It's me. I've lost it.

Cold washes over me.

"You dare to interrupt me?" Marcus says as he walks lazily towards me. He wears a strained smile, devoid of warmth or concern.

"No, Lord Centurion." 

"I'm sure I heard someone yelling while I was talking." He's right in front of me. "I do hate that. You know that. Don't you?" 

My eyes find Niall's, whose stiff frame is glued to his place, a concerned frown distorting his features.

*choice
    #Ask for his help.
        I beg for his help with my pleading gaze. His body shifts uncomfortably and with a visible sigh he starts to walk towards us.
        *goto ch2_voiceniall
    #I'm on my own.
        *goto ch2_voicemarcus  

*label ch2_voiceniall
*set ch2_niall_undermine true
Marcus merely glances at the approaching Tribune, keeping his demanding eyes on me.

"You have nothing to say for yourself?"

Niall cuts in. "I'm sure it was a mistake. Right?" He looks at me, the frown now replaced with a concerned smile.

"I will not tolerate—" Marcus starts, but with a raise of a hand Niall shuts his attempts down. Marcus squints his eyes at the man, his jaw clenched to the point of breaking his teeth, but still obeys.

He has no other choice.

He shoots me a dirty look before leaving. "Deal with it, then. [i]Lord Tribune.[/i]"

Niall looks at the retreating Centurion and lets out a small sigh. He turns to me. "Are you sure you're alright? You're not usually this reckless."

*fake_choice
    #"I'm alright. Thank you, Lord Tribune."
        *set rude -1
        *set disciplined +1
        Even if I just heard someone talk in my head, I nod. This is not the place to lose myself. Besides, maybe it was my imagination.
        
        Right? It could be that. There's no real reason to think it was anything else than that.
        
        Niall smiles at my answer, but doesn't look convinced.
    #"I don't think I'm alright."
        *set manipulative -1
        His already fragile smile withers away, his brows furrowing into a picture of worry. He looks at the men on the line-up, as if to remind me this is not the place for this talk. 
        
        I know it's not. I just… couldn't help it. The words left me without my will.
        
        But it could've been just my imagination, right? There's no real reason to think it was anything else than that.
    #I nod absentmindedly.
        My mind blanks. Evidently I'm not alright at all, otherwise I wouldn't hear foreign voices in my head. But still I give the concerned man a nod. This is not the place.
        
        But it could've been just my imagination, right? There's no real reason to think it was anything else than that.
    
        From the corner of my eye I see Niall giving me a small, but wholly unconvinced smile.

He studies me for a brief moment, gracing a strand of fleeing curl back under his brass-coated helmet.

"If you want to talk about it, you can meet me in my office later."

An offer, not a command.

He trots away back to Marcus, whose already stony features harden even more when he realizes I didn't get any sort of punishment for my behavior. Knowing him, I wouldn't have survived the encounter with just a slap on the wrist.
*goto whodat

*label ch2_voicemarcus
*set ch2_marcus_office true
"Lord Centurion, I—"
*fake_choice
    #"I was just so excited of being promoted to a Roman soldier."
        "I couldn't help my excitement. I'm sorry." I keep my eyes on the ground. No need to invite his wrath on me on top of all of this.
        
        "What a simple lad you are." A heavy pause, awaiting for my reaction at the insult. Since it never comes, he continues: "Since you're so happy, I don't think you'll mind to eat barley for the next week."
        
        "I…" There's not much to do with unprocessed barley, but I suppose the punishment is on the lighter side. "No, Lord Centurion."
        
        "Good. Remember to chew properly." He almost turns to leave but as if remembering something, he turns back and says: "You will meet me at my office."
        
        An order.
    #"I just remembered that I haven't cleaned my armor."
        "You were so shocked over the state of your armor that you had to interrupt me?"
        
        "Yes, Lord Centurion." It does sound a bit stupid, but I didn't come up with anything else.
        
        *if clothes = "cheap"
            His scrutinizing eyes comb my armor, and they focus on stains of rust here and there.
            
            "Soldier, your armor is in horrible shape."
            
            "Yes, Lord Centurion, that's what I was—"
            
            "You will clean your own armor and you will do so with every other soldier's armor in your unit."
        
        *if clothes = "fine"
            He checks my armor skeptically.
            
            "Are you lying to me, soldier? Your armor is spotless."
            
            "I just… like to keep it that way."
            
            "Uh-huh." He doesn't look convinced at all. "Since you're such an avid armor-cleaner, you will do so with every other soldier's armor in your unit."
            
        "Yes, Lord Centurion."
        
        "And you will meet me at my office."
        
        An order.
    #"I was just hearing voices in my head."
        *set marcus_voices true
        *set manipulative -1
        His thick eyebrows shoot up in pure surprise. A rare sight, one I'd probably appreciate more if I wasn't acutely frightened over my own mental state.
        
        Now that the incriminating words have already fled my mouth, there's nothing else to do but to stare helplessly at the officer in front of me. He tilts his head towards me, as if he didn't hear correctly.
        
        "You did what now?"
        
        All I can do is to nod, for no words are willing to leave my dry lips.
        
        He regains his usual expression, but instead of the usual sneered smirk, there's worry. "Meet me at my office."
        
        "Yes, Lord Centurion…"

With these words he leaves, his blood-red cloak billowing after him.
        
*if marcus_voices
    But not before glancing at me over his shoulder with his brows furrowed.
*goto whodat

*label whodat
"Optio leads you to your new barracks. Dismissed."

I'm left standing as the others pass me by. Different questions coated with the fear of losing my mind surge in me, one of them the most significant of them all: Why was the voice… familiar? As if I've heard it before in my dreams, long ago, when it used to bring me comfort.

"Move it you little prick!"

I merely nod at the already too familiar shout, my feet leading me away with my thoughts in disarray.

*page_break
We meet a few men from our new century on the way, but for some reason, their expressions are filled with confusion and hostility. I suppose the promotion is indeed quite drastic in its nature. Why did Marcus insist on this? 

I'm not sure I like the added attention.

As I open the door to our new barracks, there's already a room full of men chatting about, almost making my head hurt with their unnecessary shouting. The rooms are bare in decoration and lack any warmth, but it's a clear improvement to the tents. There's the same smell of sweat and dirt; what's lacking is the sickly scent of wet leather caused by the early morning dampness.

My eyes skim the room of already familiar men: our whole contubernium is here, as well as some unfamiliar men from our new century. They keep to themselves, observing the new men. Dizziness still occupies my mind and I barely have the strength to stand up. At least it's a reminder that I didn't imagine the voice. Is that a… good thing?

"Are you alright?" Floyd's voice yanks my attention back to him, his smile replaced by a concerned frown. Every expression comes easy for him. "You look… startled." 

Before I can answer, he erects his hand towards my head. Is he trying to… pet me?

*if floyd_parent
    Again.

*fake_choice
    #Swat his hand away. 
        I'm not his child, I'm not in the mood, and my hard gaze tells him so. Floyd's eyes widen, but he recovers quickly.
        
        "I'm sorry." He smiles apologetically, as if meaning his words. He'd better.
        
        *if floyd_parent 
            "The bad habits. I try to keep it down."
            
        *if not(floyd_parent)
            Pec grins. "You're not the only one he's treating like his pet. It's a bad habit that just keeps on giving."
            
            Floyd takes a step away from me, giving me space. "I try to keep it down."
    #Let him pet me.
        *set floyd_touchy true
        Something in me yearns for comfort after what's happened. So I merely watch his hand closing in on me before my eyelids fall closed. The urge to lean into the sudden warmth of his hand almost overcomes me.
        
        The voice in my head left me vulnerable, all the blame for my need for some peace of mind falls on it.
        
        I sigh, almost, as the touch reminds me how father used to pet me. Sometimes he called me his puppy. It was stupid, humiliating, the others laughed, but I suppose a part of me liked it. Warmth spreads through me and I almost smile, almost forgetting my fears.
        
        "Oh, so you found a new pet, Floyd?"
        
        "Shut it, Pec." His soft voice playfully commands his peer, and as I open my eyes, he's smiling at me.
        
        [i]Thank you,[/i] I almost say, but my lips are sealed.
    #Bear with it.
        *set floyd_touchy true
        My muscles tense as I brace myself for the impact with his hand. Why would he feel the need to pet me, I don't know, and just as I'm about to tell him to stop, something about his touch sends warmth across my body. My tensed muscles relax. Only a fraction, but relax, nonetheless. 
        
        The palm of his hand on top of my hair reminds me of father, the way his touch used to calm me. I told him to quit it, that I'm not a child anymore. He persisted and laughed.
        
        He always laughed.
        
        I can see the same in this man's eyes, the fact that he means to persist on this habit. And for some reason I can't bear to complain.
        
        "Oh, so you found a new pet, Floyd?"
        
        "Shut it, Pec." Floyd smiles as he playfully commands his peer.
    #"Could you not?"
        I evade his touch in time and berate him, as he should be berated. He merely smiles.
        
        "Oh, sorry Hati." 
        *if floyd_parent
            "The bad habits."
            
            "Please keep a hold of your bad habits."
            
            The lanky man with red hair bursts out laughing. "We'd all like that to happen."
            
            "I'll try my best." He smiles.
        *if not(floyd_parent)
            "You're not the only one he's treating like his pet," Pec grins. "It's a bad habit that just keeps on giving."
            
            I frown. I'm not anyone's pet.
            
            "I try to keep it down," Floyd says with a smile.

"You sure you're alright?"

I nod.

"If you say so… we have an idle evening. We should celebrate our promotion."

"Yes!" Pec shouts at the suggestion, making Maestus grimace at his howl: "There's a tavern outside of town. I heard they offer discounts for soldiers."

There's a series of agreeing nods and finally their eyes land on me.

*if ch2_niall_undermine
    Before that, however, Niall asked me to see him in his office later. Should I go?
    *choice
        #Yes. 
            "Tribune asked me to see me in his office later."
            
            Floyd nods. "What a nice surprise. I hope he has good news."
            
            I doubt it, but nod nonetheless.
            *goto_scene chapter2_office ch2_nialloffice
        #No.
            There's no need to see him right now.
            *fake_choice
                #I'm not ready to share my worries with him.
                    I haven't had time to process my own worries about what happened yet. I don't think I'm ready to do that with him.
                #I don't want to confide in him.
                    *set niall_friendship -1
                    I hardly see the need to confide in him.
            *goto_scene chapter2_tavern ch2_tavern
*if ch2_marcus_office
    Before that, however… 
    
    "I need to see the Centurion first. He invited me to his office."
    
    "Oh, right." A brief shadow flashes on Floyd's face. "Please join us when you can. I hope everything goes well."
    
    I hope so, too.
    *goto_scene chapter2_office ch2_marcus_office

*page_break
*label ch2_tinsae
[b][i]Next day[/i][/b]

This is my first time this deep in the town. Marcus asked — commanded — me to fetch him a package from a merchant. He didn't give me much directions, nor a description of her, probably reveling at the thought of me wandering lost in the city streets.

The pompous sea of togas and tunics flood the roads. They're covered under cloaks, but the different shades of whiteness of their attire shine through. Even if all of them were clad in sacks, their features would give the citizen of Rome away: the distinct expression of smelling something vile. Even the ones clad in the cheapest brown tunics sneer just the same.

The people here bended the knee to the Roman invaders quick enough. Do they miss the time before them? Do they care, since Rome has given them fancy streets and drainage systems? Or have they already forgotten?

A sight of a familiar statue of the new young Emperor halts my steps. His youthful and ridiculously handsome features (likely exaggerated to please the self-proclaimed living god) are beginning to corrode into my brain since his face is everywhere. However, there's something peculiar with this one. There's a blood-red graffiti across the lad's purple toga: 'MADMAN'.

At least someone here hates the Romans. Or, the Emperor.

Guards are making their way to the statue, their squinted eyes are already staring at me with interest. It's better to leave.

The sounds of indistinct babbling guide my way towards the forum.
*page_break
Annoyance rushes through me as another man bumps into me. There are no apologizes exchanged, not even regretful glances. 

Another bump, another surge of annoyance. I really hate this town.

Then, an aggravated shout echoes through the street, it's followed by a horrified cry of a child.

I follow the voice and find just another evidence that the Romans are vile, evil creatures: there's a man with a raised cane threatening a child, who must be no more than 7-summers-old. 

*fake_choice
    #Intervene with violence.
        *set ruthless -3
        No vile Romans will hurt any children on my watch. Just as I'm pondering between using my sword and my fists, a voice cuts through the commotion.
    #Intervene with words.
        *set ruthless -3
        "Hey you!" I shout at the man. But my voice is quickly buried underneath a more commanding one: 
    #What can I do? The boy is his property and I can't just start beating up random people in the streets.
        *set ruthless +3
        I begin to move away from the scene. Then a voice cuts through the commotion.

"Let the boy go." 

The accent the voice carries is heavy, but pleasant to the ears, almost flowing like a song. A threatening song, but a song nonetheless. The owner of the voice proves to be a woman with a pure white silken gown flowing softly in the wind. Her black hair is braided across her scalp, ending in a cloud of curls flowing freely. Golden eyeshadow decorates the onyx-colored skin of her eyelids, matching her jewelry flashing in the midday sun.

She stands tall, taller than the man, and the sense is amplified by her demanding presence. The man tries to puff his chest and with a sneer he asks:

"Who are you to tell me what to do?"

The woman doesn't say anything. She merely smiles; it's a polite smile, yet it lacks any warmth. The man takes another look at the woman, her bodyguard, and as the realization starts to undress any arrogance and defiance from his face, color begins draining from him. "I'm sorry my lady! I will behave better, my lady. I will just take this nuisance and—"

She raises her finger, motioning the man to stop his babbling. "How much for the boy?"

"It's not for sale, I—"

"How much?"

The man bites his lip and sighs. "200 denarii." 

She raises her brow, by now smiling with bared teeth. "I'm paying 20 denarii and you will accept it with grace."

The man takes a look at the massive man of a bodyguard before scrooching down. "…Fine."

She motions her bodyguard to pay the man. The boy, now free of his questionable owner, runs to the woman's arms as tears run freely from his eyes. "Thank you!"

This time the smile on her face is genuine; it's as if she's wrapping the boy in a warm blanket after almost drowning. She whispers something in his ear and this makes the smile on his features even wider. 

*choice
    #Approach the woman.
        *set ch2_tinsae_meet true
        *goto tinsae_meeting
    #I don't have time for this.
        *goto ch2_forum_tinsae

*label tinsae_meeting 
Curious about the woman and her action, I approach her. "Excuse me."

The boy hides behind her dress, taking a tight grip of her silken dress. The woman gives the boy another smile before turning to greet me. The smile she's aiming at me is clearly meant for strangers, but it's not as intimidating than the one she gave to the man before. It's mostly pleasant, but there's a layer of curiosity underneath. 

"Greetings, soldier." Her eyes quickly skims through my attire, lingering on my sword for a moment. "How can I help you?"

*fake_choice
    #"What are you going to do with the boy?"
        "With the boy?" The smile warms up as she looks at the boy and she shakes her head. "Nothing."
        
        "Nothing?"
        
        "He will have his freedom and I will purchase his mother, too. Perhaps the mother will work for me, if she'd prefer." She states that as if it's something she does on a regular basis, as if it's just another walk in the town for her.
        
        I frown at the words. That is pure charity. Why would she do that?
    #"Did you just bought him to yourself?"
        *set rude +1
        She raises her brows at me. "Why in the name of Isis would I do that?" The smile warms up as she looks at the boy and she shakes her head. "No. I bought his freedom."
        
        "But… why?" Why would anyone in this town do anything good? There must be some rotten ulterior motive underneath her actions.
        
        "Why would I save a clearly mistreated child from the hands of an abuser?" She tilts her head slightly at me.
        
        The boy takes an even tighter hold of the woman's dress before stomping his foot on the ground. "She will buy my mother, too. We will be freed and—" 

        The woman graces the top of the boy's head and gives him a smile. "That's alright, my dear." The boy quickly closes his mouth and hides behind her once more.
        
        She gives me another look, a more pondering one. "Why would you find that outlandish, stranger?"
        
        I shake my head. I suppose I shouldn't.
    #Introduce myself and then ask about the boy.
        *set ch2_tinsae_introduce true
        *set rude -2
        "My name is Hati."
        
        Her smile warms up and she nods her head gracefully. "Pleased to meet you, Hati. My name is Tinsae."
        
        "What happened with the boy?"
        
        She looks at the boy and shrugs. "I bought his freedom and I will do the same for his mother." She states that as if it's something she does on a regular basis, as if it's just another walk in the town for her.
        
        A muffled cry of joy can be heard from behind her, the child is burying his face on her dress and giggling.
        
"If you'll excuse me. I will have to proceed quickly with this situation." She motions her meatwall of a bodyguard, speaks to him quickly in a foreign language and sends him off. She takes the boy's hand and starts walking away, but not before giving me a quick nod of farewell.
*goto ch2_forum_tinsae
*label ch2_forum_tinsae
*page_break
Finally I've found my way into the Forum with no more incidents. I've searched the place, asked around, and I'm beginning to get slightly annoyed. Mainly at Marcus. He said that her shop is in the far end of the Forum, she's from the South and—

There's the woman from before. She seems to be the one I was meant to meet.

For whatever reason Camilla stands next to her, and her face is decorated with a rare expression: something resembling a smile. The duo turns to me as they sense my arrival. The woman wears a smile meant for strangers and customers, whereas Camilla's smile starts to wither away as she recognizes me.

*if ch2_tinsae_meet
    *if not(ch2_tinsae_introduce)
        The woman 
    *if ch2_tinsae_introduce
        Tinsae 
    gives me a wide smile as she recognizes me. "Oh, it's you from before." 
    
    Camilla squints her eyes. "You've met him?"
    
    "Briefly. I had an unfortunate meeting with a brute earlier. We exchanged some pleasantries."
    
"Fancy meeting you here, soldier." Camilla's demeanor is more relaxed than usual. The frown she so easily wears isn't gone, but it's mellowed. "Hati, this is Tinsae. Tinsae, Hati."

"Nice to meet you, Hati.
*if ch2_tinsae_introduce
    Again."
*if not(ch2_tinsae_introduce)
    "
Tinsae's smile subtly reveals a glimpse of her dazzling white teeth. The relaxed atmosphere these two women communicate melts the usual tension from my neck and shoulders.

*fake_choice
    #"Likewise, my lady." Keep my eyes on Tinsae.
        *set rude -1
        She seems like a woman who's seen her share of the known world. There are a few wrinkles in the corners of her eyes caused by the sun and a habitual smiling, as if she cared more about the joys of being alive than maintaining her smooth skin.
    #"Likewise, my lady." My eyes wander to Camilla.
        *set rude -1
        What is she doing here? It's weird to see her anywhere else than the fort. Now that I know her blond hair is a wig, it seems more factitious, emphasizing the mask she chooses to wear during daytime.
                
        Camilla raises her painted eyebrow at me.
    #"Likewise, my ladies." Nod at the both of them.
        *set rude -1
    #Nod.
        *set rude +1
        Camilla throws me a subdued sneer.

"What is your business here today?" Tinsae asks.

"Centurion asked me to fetch an item he ordered."

"Marcus?" Camilla cuts in, her features souring by the mere mention of the man. I can't exactly blame her.

"Yes, my lady."

"The lazy bastard."

"Now now." Tinsae cuts in, briefly touching her friend's shoulder. "Would you both like some hot beverage? I'm sure the good Centurion can wait a bit."

*fake_choice
    #"I would love that."
        I'm not sure how Marcus will react to me being late. On the other hand, I'm also not sure if I care. Annoying him is an added bonus.
    #"I'm not sure if--"
        Camilla cuts in: "Of course Hati joins us." 
        
        She doesn't bother to check with me if I want to do this. Why? Is she so keen on annoying Marcus?
        
        At least I can't exactly blame her for that.
    #Decline the offer.
        Just as I'm about to say no, Camilla cuts in: "Of course Hati joins us." 
        
        She doesn't bother to check with me if I want to do this. Why? Is she so keen on annoying Marcus?
        
        *fake_choice
            #Firmly say no.
                *set camilla_friendship -1
                "No, ma'am. I have a package to deliver."
                
                Camilla turns her gaze at me, clearly displeased that I'm not playing along with her as easily as she'd prefer. "Soldier. Who do you think has more power in this situation?" She's clearly waiting for an actual answer. 
                
                Tinsae shifts uncomfortably and opens her mouth to speak, but Camilla silences her with a pointed look. Tinsae sighs and shakes her head but not before giving me a sympathetic look.
                
                Finally I give her the answer she wants: "You have, ma'am."
                
                "The problem solved itself in a matter of moments. Now, please, Tinsae, we would like to join you for beverage."
                
                Tinsae gives me another look before shaking her head.
            #Just go with it. As long as it annoys Marcus.
            #Just go with it. At least I can get to know Tinsae.
                *set tinsae_friendship +1

"Wonderful news, please wait for a moment," Tinsae says before turning to a woman carrying baskets behind her. She speaks in a peculiar language I haven't heard before. It rings soft, its intonation flows rhythmically. Soon she gestures us to follow her inside the shop. 

*page_break 

The strong scents of different herbs, wine, and incenses mark my entrance to the shop. There are different luxury items from all over the world on display: little ivory statues, different shapes of golden jewelery, cosmetics, fabrics. The wealth displayed here is almost dizzying. This certainly explains the armed guards on the doorway.

Tinsae just smiles as she takes a glance at my reaction.

"Please excuse the mess," she says as we enter the backroom. It looks neither messy nor something to apologize for. There are richly-decorated carpets in front of a low table. The decoration is not Roman; the color scheme is too bright and joyful for them. Instead, it's relaxed and homely, yet luxurious at the same time.

"Would you care for a beverage of my home—?" She cuts herself before turning to me. "Oh, but do excuse my rudeness, Hati. I haven't even told you where I'm from." She berates herself. "My homeland lies deep in the South. Kingdom of Aksum, I call it. The Greeks labeled it Ethiopia, and the people Ethiopians, in their vast imagination." 

Camilla snickers. It takes a moment to get the joke, but from what little I understand of Greek, the term refers to sun-burnt faces.

"Have your heard of my country?"

"No, my lady." My teacher never bothered to extend my education to include faraway lands. The people from that far from the South were rare in the North, only a few merchants dared to venture to our village.

"I don't expect my countrymen to know of these Northern places, so it is quite alright. But please, I'm no lady, just a simple merchant."

Camilla cuts in: "She's lying, she ought to be called a lady." 

Tinsae raises her hand to banish Camilla's words. "Call me Tinsae."  

*fake_choice
    #"Why did you leave your country?"
        *set tinsae_friendship +2
        She gives me a smile as she sits down with a grace of a red deer. "I'm flattered by your interest in my story. It is, however, a tale for another time."
    #"Do you miss your home?"
        *set tinsae_friendship +2
        She smiles wistfully, clearly due to remembrance of her home. I recognize the smile. It almost makes me smile with her, two foreigners ripped from their roots.
        
        "Sometimes I do yearn for home. The scent is different. The looks of people, the sounds, the nature, the animals, the insects…" She sighs as her gaze finds mine. It's a gaze of vast life experience with a touch of melancholy. "But make no mistake, I find beauty in Germania, too. The people here are peculiar and the forests magnificent. How about you, Hati? I heard that you hail from Central Britannia. I can't claim to have visited that part of Roman Empire yet."
        *fake_choice
            #"I do miss my homeland."                
                "It seems we're quite similar in that sense." She smiles.
            #Just nod.
                I merely nod at her, not ready to talk about my home with her. Besides, it would all be a lie, since I can't tell her where I'm actually from.
            #"Yes, I'm from Britannia."
                She nods."I do hope I could visit the country. I hear the nature is beautiful. But also cruel."
    #Nod.
        I decide not to question her further. She smiles.
        
"Now, the beverage. It can be harsh on the tongue, but I promise it will be worth it. You will get, uh… used to the taste. It's not something truly caught on even in my homeland, but I do hope it will gain some fame in the future." She turns to her servant waiting for orders. "Abebe, my dear, would you be so kind and start roasting the beans?"

"The scent is part of the ritual. It's divine. I know the Romans aren't fond of scents from the kitchen, but I hope you won't be offended."

Camilla dismisses her worry: "Hati doesn't share the customs. It's fine." Tinsae looks at me to confirm the statement. I'm not really in the know of Roman nobility's smell customs and that one sounds ridiculous. They don't like the smell of food?

Tinsae shares my puzzlement. "It's… peculiar, yes. The slaves usually prepare the food, so it's not proper for a nobleman or a noblewoman to smell such scents. Did I explain it correctly, Cam?"

"It is somewhat dumb, yes." She admits.

The scent of roasting beans flow through the room, replacing the aroma of incenses and herbs with its nutty smokiness. It's pleasant, if a little overpowering.

After some roasting and boiling and cooking, a cup of steaming brown liquid is brought in front of me. Tinsae looks at me with an anticipating smile, awaiting for my judgment. I bring the cup to my lips as the smell of burnt nuts overcomes me. The smell is extremely strong at this proximity, almost nauseating.

As an instinct, I put the cup back on the table with a deep frown. 

Camilla frowns at my table manners and opens her mouth with a clear intent to reprimand me before Tinsae's giggle stops her. 
        
"That is quite alright, it's a natural reaction. No need to force yourself, it took some time for Camilla to get used to it, as well."
        
Camilla sighs and nods. "You'll get used to it."
        
Tinsae, still giggling like a teenager, continues teasing her friend: "But it's not good? Don't think I haven't seen your wrinkled nose whenever you drink it."
        
If I didn't know any better, I'd swear Camilla's ears change their color into a hue of red. 
        
Tinsae turns her attention back to me, evidently satisfied with the amount of scrutiny she put her friend through. "So, do you want to taste it?"

I peer at the vile-smelling liquid and bite the insides of my cheek. 

*fake_choice
    #I won't touch that thing.
        *set rude +2
        *set camilla_friendship -1
        I shake my head, pushing the cup away from me. 

        Camilla frowns and stands up with a . "Are you a child? No, not even children behave in such a manner. She offered you her—"
        
        "Cam, it's alright." Tinsae smiles and takes the cup away.
        
        Camilla sits down, but not before throwing me a glance of death.
    #Drink it.
        *set rude -2
        *set camilla_friendship +1
        I stop breathing in order to block the smell from my nostrils and brace myself for the taste. 
        
        It tastes as vile as I expected: acid invades the whole of my mouth, assaulting every tastebud with such vigor it takes every fiber of my body to fight the urge to frown,
        *if disciplined <=50
            but I fail, the experience too harsh to bear with a straight face.
            
            [i](failed discipline check)[/i]
            
            I raise my gaze to the two women snickering like teenagers behind their hands. When they notice they're caught on the act, both erupt into laughter.
            
            "I'm sorry Hati, this is rude of us," Tinsae says through her giggles. "You don't need to drink it if you don't want to. 
        *if disciplined >50
            and I succeed, my being resembling of an expressionless statue, despite my tastebuds trying to escape my mouth.
            
            [i](successful discipline check)[/i]
            
            Tinsae gives me a small applause. "Such nerves of iron! Extremely impressive, it's no wonder you're a soldier. Don't you think, Camilla?" 
            
            Camilla nods and looks at me with less scorn than usual. 
            
            Tinsae continues: "Did you like it, my dear?"
            
            *fake_choice
                #"Not really."
                    *set manipulative -2
                    "Camilla said the same thing. If I recall correctly, she called the experience akin to drinking acid."
                    
                    I nod, approving of her assessment.
                    
                    "Yet you still offer it to me," Camilla says with a slight smile.
                    
                    "Why of course, it's a weekly entertainment of mine. A test, if you will. How long will it take for a Roman to get used to it."
                #"It's alright."
                    *set rude -2
                    Tinsae smiles before shaking her head. "Of course it is, my dear. Whatever you say. I promise that other edibles I offer will be less offensive."
                    
*page_break
A cat appears in the room, making their way in a slothful pace, quickly taking a glance at me.

"Did you come greet the guests, Alitash?" Tinsae turns to me. "You can pet him, he's friendly."

As if in cue the cat starts to make his way towards me with silent decisiveness. His fluffy butt moves with more grace than I expected and it's not long after he's staring at me with his big, green eyes.

*fake_choice
    #Offer him my hand.
        I offer my hand to the cat to sniff it, as is accustomed when meeting with unfamiliar animals. I'm not familiar with cats, but animals tend to respond well to calmness and slow movements. The cat takes a quick sniff before pushing his soft head to the exposed palm. He purrs his greeting before demanding a place in my lap. I give in and he jumps on me before curling up on a small ball of fur.
        
        "He took a liking to you, how nice."
    #What does he want? I'm not good with cats.
        *set ch2_catsnope true
        I stare back at the cat, not knowing what to do with him. I've seen cats, of course, but just a few and never this close. It's hard to say what he wants from me, it's as if he's judging me silently.
        
        Perhaps I should look away in order not to aggravate the creature. Who knows if the stare is considered rude with them.
        
        As my gaze is elsewhere, there's a distinct feeling of pressure on the side of my thigh. The cat is persisting on getting something from me. 
        
        What? What do you want?
        
        He only offers a demanding meow as an answer. His eyes peer into my soul and he shows no sign of leaving. Is he demanding my spot? 
        
        *fake_choice
            #Move away.
                *set rude -2
                "Fine." I give in to the resilient ball of fur and stand up to let him invade my spot on the carpet.
                
                There's a muffled giggle on the other side of the table. 
            #Stare back at him.
                *set rude +2
                It seems that he wants to dominate me, but I'm not here to be played for a fool by a soft ball of fur. I squint my eyes at the cat and tell him that I'm not moving anywhere. He looks at me with little care, giving me another meow in response.
            #Ask him what he wants.
                "What do you want from me? Will you leave me alone if I give you snacks?"
                
                He merely meows in answer.
                
        "My dear, you're not accustomed to cats?"
        
        "Not really, no."
            
        Tinsae smiles and beckons the cat to come to her. "It takes time to learn to read them. Their language is quite subtle."

Camilla's voice cuts through the pleasantries: "Did you hear that the army is going to proceed into the land of Taexali tribe? All the way in the North."
*page_break

I try not to squint my eyes at the words. I'm not sure if I fail, since for some reason, Camilla's eyes are peered onto me. Taexali… They're going to proceed even norther. My cousin is a Taexali, I have distant family there. 

Tinsae's gaze quickly darts to me before turning back to Camilla. "What do you mean?"

"Don't you think the Emperor is a fool? To venture so far. The people there are…" She glances at me, as if searching the right word. "Wild."

"Please, you know Hati is from Britannia."

"Not that North. Right?"

"Right…" I say, searching for any clues as to why she's talking about these things. It seems like she knows I'm from there. Or is she bluffing? Am I showing too clearly that the topic interests me?

She continues: "Unless you have some relatives there? Distant ones?"

*fake_choice
    #"Distant ones, yes. I'm bothered by the news."
        *set manipulative -1
        "Who wouldn't be!" Tinsae quickly steps in with her hands in a defensive position, evidently trying to stop her friend from talking. "We do not need to talk about these things. Did you see the—"
        
        Camilla continues without a pause, the corner of her mouth curling into a small, sadistic smile: "You must hate the Emperor. For him to be responsible for killing your relatives in cold blood—"
    #"No."
        Camilla continues without a pause, the corner of her mouth curling into a small, sadistic smile: "So you have no one there? You don't care that the Emperor is rampaging the North? He's the one responsible for all of that."
        
        "No, I don't care," I lie.
    #Remain silent.
        Camilla holds my gaze, waiting for me to speak. When I give her no words, she continues: "No? You don't care that the Emperor is rampaging the North? He's the one responsible for all of that."

"Cam, stop that," Tinsae says with more force. "This is unlike you."

Camilla merely smiles at the accusation and returns her attention to Tinsae. "I will apologize, if you want me to." The apology is neither genuine nor aimed at me. Go figure.

Tinsae sighs, clearly used to her antics. She gives me a look, as if to ask if I'm alright.

*fake_choice
    #I'm still rattled by the news, but I give her a nod and a grateful smile.
        I can't deny my shaken state, but there's something about this stranger's smile that melts some of the tension away from my shoulders. And so I surrender, giving her a barely noticeable smile. Her features blossom into a pleasurable smile of her own.
    #My thoughts wander to the people in the North. My people.
        There are still relatives, friends, allies up there. The Romans are slaughtering them as we speak.
        
        Small beads of cold sweat start to form on my upper lip. 
        
        It takes a moment before I realize Tinsae is still looking at me. Instead of waiting for an answer, she seems to inspect my… well-being?
        *fake_choice
            #Shake my head as if to say 'I'm fine'.
                She gives me a mouth shrug with a tilt of her head and lets the issue go.
            #Shrug and look away.
    #Remain silent.
        Tinsae nods, seemingly not taking offense over my non-responsiveness.  
    
Camilla ignores us, inspecting her half-empty cup with a small grimace.
    
*page_break
After a few more exchanged pleasantries Tinsae stands up.  "I will get the package for your Centurion, I hope he doesn't mind the wait."
*page_break
[b][i]Back outside[/i][/b]

The violent noise of the Forum greets me with its force once again, only this time I'm holding the package Marcus ordered. 
*if ((build = "heavy") or (build = "average"))
    It's heavy, but nothing I can't handle.
*if build = "lithe"
    I struggle with its weight, but try to appear as if nothing is wrong.

Also, there's the feeling of Camilla's demanding eyes on me.

"What?"

"Walk ahead of me," she says, her tone equally as demanding as her gaze.

"Why?"

"Just do it, soldier."

*fake_choice
    #"No." I won't be ordered around.
        She squints her eyes and starts walking in a brisk pace, ignoring my existence.
    #"Fine." I don't know what this is about and despite her rudeness, I don't see a reason to decline.
        *set ch2_humanshield true
        She nods, as if she expected the outcome. It almost makes me want to take my word back, but what's done is done.
    #"Yes, my lady."
        *set ch2_humanshield true
        She nods, as if she expected the outcome. It almost makes me want to take my word back, but what's done is done.
    #"Whatever." I comply, but give her a small eyeroll in the process.
        *set ch2_humanshield true
        She squints her eyes at me, but my obedience seems to substitute my lack of interest, as she gestures me to move.

*if ch2_humanshield
    We begin our journey and soon my role for the road is revealed: I'm meant to be her human shield, fending off the incoming hoards of peasants. The crowd isn't overpowering, and many give way for the Roman noble lady and her escort. Many keep their eyes to themselves, not daring to stare at the highborn woman and her armed escort.
    
    I peer behind me only to see Camilla's featureless face, uncaring if I find my place as her shield degrading or not.
    
*if not(ch2_humanshield)
    We walk side by side, neither of us willing to walk ahead of the other. It seems her intention was for me to act as her meatshield, fending off the incoming hoards of peasants. Now, lacking her shield, she has to bump shoulders with common people, her frown deepening with every collision. However, many give way for the Roman noble lady, unlike they did for me.

The commotion of the forum dies down as we proceed through the gates of the town. The road continues with the view of already familiar tombstones, some clear white, others caked in moss and dirt. 

*if ch2_humanshield 
    The need for a human shield passes with the lack of people, and I slow my pace closer to Camilla. If anything, it feels awkward to walk in front of someone. She doesn't acknowledge the change of my position, her gaze is strictly aimed ahead.
*if not(ch2_humanshield)
    I keep my pace next to Camilla, my gaze idly wandering though the forgotten stones. 
    
Suddenly she yelps.

"What is it?" I ask.

"Nothing," she snaps as she rearranges her coiffure. It seems she almost fell over. She squints her eyes at me, as if in challenge.

*fake_choice
    #Something about her need for appearing unfazed makes me smile. It's ridiculous.
        My smile, as expected, makes her frown deepen. 
        
        "What do you think you're grinning at?"
            
        "Nothing, my lady."
        
        Her eyes squint as she keeps staring at me. Soon her icy stare is cut to a close and she yelps, again.
        
        She's falling.
        
        *fake_choice
            #Catch her.
                *set camilla_friendship +2
                *set ch2_camilla_stare true
                *set ch2_box_break_marcus_wtf true
                I act almost in reflex, throw the package on the ground with a loud shattering of glass following the act, and try to take the falling woman in my arms before she hits the ground.
                *if build = "lithe"
                    However, I can't get a good hold of her. She's too heavy, or I'm too weak, either way the combination didn't work and I fall with her. With an undignified thud we end up on the ground.
                    
                    Her silken-clad body is beneath me, her eyes widened at my proximity. The scent of her perfume assaults my senses, almost sickly sweet with the already familiar scent of spices. Her face is close, her features stripped naked with surprise. She holds my gaze, neither of us sure how to act in the situation.
                    
                    *fake_choice
                        #Get up with a grin.
                            I give her a grin, which manages to raise a hue of redness beneath the makeup she wears. Before she can react, I'm already on my feet. She gets up as quickly as I did, her gaze examining the area. A woman passing us by whispers something to her companion, their gazes scrutinizing Camilla.
                        #Apologize and get up.
                            "I'm sorry!" I almost shout at her face. She shakes her head and tries to shove me away.
                            
                            "Just get off of me, you oaf!"
                            
                            I'm already up and she follows my example, her gaze examining the area. A woman passing us by whispers something to her companion, their gazes scrutinizing Camilla.
                        #Stay put, I can't move.
                            I can't move, I don't know why. It's like I'm immobilized. I open my mouth but no sound comes out. She mimics the gesture and soon the expression changes into that of a fear. 
                            
                            "Please, get off of me!"
                            
                            The terror in her voice makes me jump away.
                            
                            She gets up as quickly, her gaze examining the area. A woman passing us by whispers something to her companion, their gazes scrutinizing Camilla.
                *if ((build = "average") or (build = "heavy"))
                    I get a good hold of her and manage to stay upright. At this proximity, the scent of her perfume assaults my senses. It's almost sickly sweet with the already familiar scent of spices. Her face is close to mine, her features stripped naked with surprise. It's the first time I've seen such raw emotions from her. Her widened eyes hold my gaze for a moment, neither of us sure how to act in the situation.
            
                    Then, her eyes flash with fear and she jolts away. I peer around and see a woman passing us by, she's whispering something to her companion, their gazes scrutinizing Camilla.
            #Watch her fall.
                *set camilla_friendship -2
                She falls flat on her face, her wig flying off like a projectile followed by a barrage of curses.
                
                *fake_choice
                    #Offer a hand.
                        *set camilla_friendship +1
                        I can't just stand by and watch as she tries and fails to get back up with her dress tangled on her feet. However, she throws me a spiteful gaze and refuses to take a hold of my expecting hand.
                    #Snicker.
                        *set camilla_friendship -5
                        I watch as she tries and fails to get back up with her dress tangled on her feet. I can't help but to snicker at the display, which only manages to deepen her flushed frown. She throws me a spiteful gaze, looking ready to take my head for the deed.
                    #Remain silent.
                        *set camilla_friendship -2
                        I watch as she tries and fails to get back up with her dress tangled on her feet.
                She picks up her disheveled wig, her jaw clenched. "Not one word."
                
    #Avert my gaze and continue to walk in silence.
        No need to irritate her further, it's better to just walk in silence.
    #Two can play this game: Stare her down.
        *set camilla_friendship +5
        *set ch2_camilla_stare true
        And so begins our staring contest. She won't budge, and neither will I. We keep walking and staring each other with silent hostility before the inevitable happens:
        
        I stumble on something and start falling to the ground.
        
        Camilla's reflexes are fast. 
        
        *if build = "heavy"
            *set ch2_box_break_marcus_wtf true
            However, she has no strength to hold me up and she falls with me. I almost crush her silken-clad body underneath as she yelps in both pain and surprise. A strong whiff of her perfume almost overcomes me. Her face is close to mine, her features stripped naked with surprise. She holds my gaze, neither of us sure how to act in the situation. Soon, however, anger takes over her features: 
            
            "How can you stumble on a flat road?"
            
            "I'm sure there was a root—"
            
            "A root! Get off of me, you oaf!"
            
            I lift myself off of her. She quickly stands up, but instead of more yells, she keeps her gaze on the ground. The tips of her ears are bright red as she starts wiping dirt from her cloak.
            
            "How much do you even weigh?" She asks.
            
            "More than you lift, apparently."
            
            She looks at me with raised eyebrows before a loud laughter escapes her. She covers her mouth quickly, her gaze on something further away. There's a woman passing us by, whispering something to her companion, their gaze scrutinizing Camilla.
        *if ((build = "average") or (build = "lithe"))
            She keeps me up with surprising strength. At this proximity, the scent of her perfume assaults my senses. It's almost sickly sweet with the already familiar touch of spices. Her face is close to mine, her features stripped naked with surprise. It's the first time I've seen such raw emotions from her. Her widened eyes hold my gaze for a moment, neither of us sure how to act in the situation.
            
            Then, her eyes flash with fear and she jolts away.
            
            "Who stumbles on their own feet?" She asks with the tips of her ears shining with red hue.
            
            "I'm sure there was a root—"
            
            "This is a stone road."
            
            My gaze falls to the ground to see the truth in her words. There are no roots, no grass. Only dirt and stone.
            
            "I see."
            
            A snicker quickly dies on Camilla's lips as her gaze sharpens on something further away. There's a woman passing us by, whispering something to her companion, their gazes scrutinizing Camilla.
            
*if ch2_camilla_stare
    The two women continue their walk with haste when they notice Camilla's hateful eyes. With her jaw clenched she starts walking away from me and the women, straightening her dress in the process.
    
    *fake_choice
        #Run after her and ask about the women.
            "Did you know them?"
            
            "No."
            
            "Why did they look at you like that?"
            
            She stops and sighs, apparently annoyed over my ignorance. How could I know about stupid Roman customs? 
            
            "I was seen hugging a strange man who's not my husband." Her steel gaze is on the ground. "On top of that, I have no chaperone with me."
            
            "Chaperone?"
            
            "Don't you Britons have these things? Can your highborn women just walk freely outside?" She raises her gaze to me, as if to blame me for Roman traditions. But she doesn't. Instead, she just bites her lip and starts walking. "Don't answer."
        #Remain silent.
    
*if not(ch2_camilla_stare)
    The walk continues in silence and without any further incident. Camilla keeps her gaze strictly ahead of her, not giving me even a glance.

*page_break
The walk is not long and as we enter the barracks, Marcus is awaiting our arrival.
*comment tarkista toi 
*if camilla_friendship >=5
    Camilla leans over: "Thank you." At first, I'm not even sure I heard her correctly. However, judging by Marcus's newly-forming grin, it seems he did — or at least read it from her lips. Camilla scoffs as the grinning officer gains up on us.
    
    "Fuck off," she snarls and leaves. Marcus stands unfazed, as if used to her hate. He turns to me, his features mockingly mortified: "Did you hear that, soldier? What kind of language is that for a lady to use?"
*if camilla_friendship <5
    Camilla lets out a barely audible 'ugh' when she sees Marcus. She glances at me but says nothing, and leaves before he catches up on us.
    
    "She left in a hurry. Did you insult the poor woman?"
    
    "No, lord Centurion." He seems to have done it himself.
    
"Neverminding that… You're late."

"Lord Centurion, she wanted me to—"

"Is she your superior?"

"No, Lord Centurion."

"Am I your superior?"

"Yes, Lord Centurion."

"Do you see a problem here?"

"Yes, Lord Centurion."

"Do I hear an apology?"

*fake_choice
    #"No, Lord Centurion."
        "No?"
        
        "No. Lord Centurion."
        
        "Hm. I suppose I don't. How weird is that."
    #"Yes, Lord Centurion."
        "I apologize, Lord Centurion."
        
        "Let this be the last time." He wags his finger at me with mocking seriousness. 
        
His tone is lighter than usual, his smile almost genuine. "Anyway, hand over the package."

*if ch2_box_break_marcus_wtf
    "I…" I start, but there's no good way to tell him about this. So I simply show him the wooden box, now holding inside mere debris of clay shards.
    
    "You…" He starts, too, staring at the box. I await for his reaction to kick in as brown liquid stains my hands. It's sticky, and I have no desire to know what it is. 
    
    Finally, he snatches the box from my grasp with a groan. "You little moron!" He opens the box and the look on his face distorts into one filled with pain as he starts collecting the shards of clay. It almost makes me feel bad about what happened.
    
    Almost.    
    
    I peer at the shattered vials. One of the labels says 'Crocodile excrement'. Was he planning on eating that? A small surge relief washes over me: at least I denied him his source of poop.
    
    Marcus is still staring at the mess I brought him. "Why?" The question leaves his lips without strength behind it.
        
    *fake_choice
        #"It was Camilla's fault, Lord Centurion."
            He rubs his temples. "Of course it's the hag's fault."
            
            "Hag?" That's a bit excessive. How can he insult the wife of the Legate so freely?
            
            "Yes, soldier. A hag. Want me to spell it out for you?"
            
            "No, Lord Centurion."
        #"I'm sorry, Lord Centurion."
            "You're… sorry. You're…" He seems to taste the word 'sorry', deems it spoiled, and spits it on the ground. "Sorry! Sorry doesn't bring back the birthday gift."
            
            I suppose it doesn't. I can do nothing else but shrug at his peril, and he gives up.
        #Shrug. I don't care.
        #Remain silent.
        #"What was the poop for, Lord Centurion?"
            The corner of his eye twitches. "I was going to make you breakfast out of it."
            
            Was that a joke? 
    
    He still lets out a small painfilled groan as he puts the box down. He gives it a final look before finally starts walking away from the scene.
            
    I suppose he wants me to follow.
*if not(ch2_box_break_marcus_wtf)
    I do as he says, and he snatches it from my grasp with little grace. "Finally!" 

    I peer to see if he opens the package, just to see what makes a vile man like him that happy. He opens it and examines different clay vials one by one. One of the labels says 'Crocodile…' excrement?

    Are those for him? Does he plan to… eat it?
    
    *fake_choice
        #...I don't want to know.
            I watch the man stuff the vials back to the package. Some things are better left unknown.
        #Ask about it.
            *set marcus_friendship +1
            "Can I ask, Lord Centurion?"
        
            "If you insist, since you so helpfully brought these to me. Even if you were late." He stuffs the vial back in to the package. 
        
            "Are you planning on eating those?"
        
            His hand stays in place, hovering over the package. "Eating crocodile shit? Why of course, it's my breakfast."
        
            I nod, slightly disgusted but half-expecting the answer. 
        
            He puffs. "No, you little moron. They're cosmetics. There's a birthday coming up."
        
            He has friends? Friends who put poop on their face? His brow furrows as he apparently reads my mind.
        
            "Of course I have friends."
        
            I wouldn't say that's a matter of 'of course', but I suppose it's best to leave the topic if I don't want to eat barley for the next week.
        
    "Help me with these." He doesn't wait for my answer and walks away with the package left behind.

*page_break
Just as we're about to enter his office, a high-pitched voice stops us on our track: "Oh! What's that?" It sounds overly excited to fit the usually stern setting. A child. A familiar voice follows it:

"It's a hundred years old scroll. Your uncle wouldn't want you to touch it."

Marcus's features tense as his hand hovers over the door handle. The musing is soon followed by Niall's conspiratory addition:

"But since he's not here—"

That pushes Marcus over the edge, he opens the door with little regard to keeping himself composed and races to the scene. The two people in the room freeze in their places, gawking at the stomping Marcus who yanks the scroll away from the child's hands.

"You," he rumbles. His eyes are on Niall, who's gathered himself from the surprise and gives him a big smile. 

"Good timing! I was just saving the scroll from her dirty little hands—"

The girl, perhaps 6 summers old, yelps: "Stop lying! You said I could touch it!" 

Marcus stares at the duo the scroll in hand, the corners of his eyes twitching with rage.

*if ch2_niall_undermine
    "It's not enough that you undermine my decisions, now you're… defiling my scrolls."
    
*if ch2_box_break_marcus_wtf
    He adds under his breath, barely audibly: "First my package, now this…"
    
"I would've bought you a new one if she broke it—"
    
"You can't buy the first edition of Martial's Epigrams!" Marcus booms as spit flies from his mouth. The room falls dead silent. The girl's eyes start to gather fresh tears.

*fake_choice
    #Comfort the girl.
        *set antonia +1
        "Oh, for the Twin's sake." A mutter escapes me as I stride past the raging Centurion towards the scared little girl. She recognizes my intent and with the tears now freely running from her eyes, she runs towards my arms.
        
        "He said I could touch it—"
        
        "I know. I heard it." I cast an accusing glare at both Niall and Marcus. "You shouldn't put children in between your petty quarrels."
        
        From the corner of my eye I see the two officers looking at each other.
        
        Niall is the first to speak, his hand raking his messy hair. "I'm sorry."
        
        Marcus, however, doesn't say anything. He caresses the scroll on his hands and lays it gently back to its place.
    #Tell Marcus to calm down.
        *set antonia +1
        "Lord Centurion, calm down." My voice cuts through the quarrel, halting the chaos in the room. "There was no harm done and you're over-reacting."
        
        Only a couple of tears escape the girl's eyes before she nods sternly, mimicking my words: "Yes, uncle. You're over-reacting."
        
        Marcus looks at me with an incredulous look on his face before shaking his head. "Fine."
        
        The girl gives me bright beam for taking her side. "Thank you, sir!"
        
        I give her a small nod and she beams even brighter.
    #Blame Niall.
        *set antonia +1
        "You should blame Niall, Lord Centurion. He clearly urged her to do it."
        
        Niall blushes, probably due to anger or fluster, or a combination of both. Either way, his face is as red as a beetroot. The girl, however, swallows the tears and gives me a bright beam. "It's true. Uncle Nya said I could touch it."
        
        I nod in understanding, silently judging the weird nickname.
        
        Marcus lays the scroll gently back to its place. "I am blaming him."
        
        "Everyone is against me," Niall pouts, raking his messy hair. "I'm sorry."
    #Remain silent and leave.
        This is none of my business. The girl starts crying as Niall ponders on between going to her and appeasing to Marcus. The scene is chaotic. It's better to leave quietly.

*if not(ch2_box_break_marcus_wtf)
    "Lord Centurion, where do I leave the package?"
    
    "…Leave it on my desk."

    I nod, place the package on the table and leave the chaotic scene.
    
*if ch2_box_break_marcus_wtf
    There's nothing preventing me from leaving, so I start to sidestep toward the door.

*if antonia = 1
    But not before the girl gives me an enthusiastic wave with a shriek of 'see you later'.

*page_break
[i][b]Some time passes…[/b][/i]

The hopes of coming up with some sort of plan of action — any kind, really — dies with nature. Decaying yellow leaves fall down in a soft sway with the wind. One of them lands in front of my spade and I spear it with little thought.

"Keep digging, you worthless maggot!" Optio shouts next to my ear, torturing my ear drums.

The ditch has been digged and re-filled again and again, it stares at me and my blistered hands.

"What did I just say?" He shouts louder, as if I didn't hear him the first time. The saliva from his mouth smacks with the skin of my cheek as I stifle the urge to wipe the mugus away. He'd just spit a new load if I did that.

"Yes, Lord Optio," I say in a loud, steady, emotionless voice as I bury my shovel into the soil of clay. It's extremely heavy to lift, 
*if build = "heavy"
    even I'm struggling to keep up.    
*if ((build = "average") or (build = "lithe"))
    and my strength has depleted about a hundred shovels of clay ago. Still
I keep going, even if by now the inside of my mouth is nothing but bleeding flesh. 

"You little shits, getting promoted like that," the Optio mutters behind his breath. Our contubernium was ordered to dig ditches while the rest of the century is training elsewhere.

As I struggle to lift another shovel, a familiar duo catches my attention. Camilla and Niall walk past our dig-site. Niall's face lightens up with a smile as Camilla mutters something to him. She almost wears a smile herself. However, it's hard to say with her underlying sourness. Both of them stop to look at the muddy men in the clay ditch.

*fake_choice
    #Look at Niall.
        *set ch2_ditch_niall true
        *set niall_friendship +1
        When our gazes meet, his face brightens up with recognition. I keep my eyes on him, partly wondering what he's doing here, partly confused why he's even looking at me. His expensive cloak looks warm and cozy, the fur on the collar emphasizing the image, and it makes me even more aware of my own wet and freezing tunic. 
        
        Then he mouths the words: "Look out."
        
        Look out for wh—
        *goto ch2_look_away
    #Look at Camilla.
        *set ch2_ditch_camilla true
        *set camilla_friendship +1
        She's clad in a warm-looking woolen cloak, making me even more aware of my own wet and freezing tunic. The rare smile on her face withers away as her gaze wanders through the men, her expression returning to her usual sneer. As her eyes meet with mine, they focus. She takes a quick glance at my muddied tunic before looking at something beside me.
        
        What is it—
        *goto ch2_look_away
    #Look at the ground.
        *set disciplined +1
        I'm not supposed to look away, I'm not interested in the inevitable beating of the officious Optio, so my gaze lays firmly on the muddy ground. I dig until there's nothing but soil in my mind, muddying the vision into a mere sludge of brown. 
        
        Then, there's the welcomed cracking shriek of the same man I so loathed to previously hear.
        
        "That's good enough, you maggots. Leave."
        *goto ch2_bath
        
*label ch2_look_away
"Did I tell you to stop?!"
        
Iron rod smacks my shin. A soundless groan escapes me as I keep standing still — only barely. Still I won't give him the satisfaction of flinching. It's a familiar battle of the wills, it must be the reason he likes to single me out from the crowd.

I deny him the reaction he so yearns for.

*if ch2_ditch_niall
    During the time of my beatdown, Niall has taken a few steps towards us. He wears a deep frown on his face as his gaze is peered at the man holding the violent rod. "Optio!" he shouts.
    
    Optio turns to the arriving Tribune and salutes him, as one should. "Lord Tribune?"
    
    There's a moment of hesitation, a quick glance thrown at my way before the interrupting Tribune says: "I trust everything is in order?"
    
    "Yes, Lord Tribune."
    
    "How many times have they dug the same ditch?"
    
    "Multiple times, Lord Tribune. It keeps them in shape," he states it as a fact, evidently finding the question confusing.
    
    "Yes, of course." The target of Niall's gaze switches between my eyes, my muddied clothes, and Optio. Zoilus frowns and switches his gaze towards me, too, his fingers twitching over his rod. 
    
    "Optio!" Niall interrupts his evident thought process with a shout. "Isn't it time already for evening routines? Or has the unit done something to deserve such punishment?"
    
    "I suppose they haven't done anything, Lord Tribune," he says with some hesitation before nodding. "Yes, Lord Tribune."
      
*if ch2_ditch_camilla
    As I wait for another blow, my eyes find a peculiar sight amidst all the mud and one raging Optio: Camilla peers at me behind Zoilus. She wears an already familiar frown as her gaze quickly skims the state of my clothes and turns her attention to the Optio.
    
    "Optio?" The hem of her dress is stained with mud, but she pays it no mind, her iron gaze peered on Optio.
    
    "My lady!" He turns to her and salutes her with vigor, yet there's a layer of hesitation and puzzlement over why the wife of the Legate stomped into the training grounds. Her presence is a bright pop of color in the middle of all the hues of brown and soil.
    
    "What are you doing here?" she asks with an emotionless voice, commanding an answer, despite not being a part of the chain of command.
    
    "We're digging a ditch, my lady."
    
    Was that a try at humor? Or didn't he think of anything else to say? Either way, Camilla's brows furrow as Optio takes a step away from her.
    
    "Indeed." She takes a look at the area. "I suppose it is quite thoroughly digged, wouldn't you say?"
    
    "But the orders of the Cent—" His words are cut short as Camilla's eyes bore into him. "I… suppose it is, my lady."
    
He turns to us, clearly not happy about the turn of events but lacking authority over the intruder.
    
"Move it, you maggots, you're free to go!"

Silent groans of relief move in waves through the men colored with an occasional sneeze. 

*if ch2_ditch_camilla
    Camilla glances at me. Her cold eyes would freeze my soul if I wasn't already in a state of hypothermia, but her actions speak louder than her facial expressions ever could. Why would she help me?
     
    I fully expect her to have ulterior motives, but it's hard to see her goal with this sudden act of… kindness? As the Northern wind invades my wet clothes with its icy daggers, I decide to let this slide for now. She does so, too, and starts walking back towards puzzled-looking Niall.
    
*if ch2_ditch_niall
    Niall smiles and nods before leaving. His face and demeanor speaks of the same warmth he showed through his actions. The question is: Why?

    What does he have to gain?
    
    It's hard to see any reason behind his sudden act of kindness, but as the Northern wind invades my wet clothes with its icy daggers, I decide to let this slide for now. I spare him one last glance as he makes his way back to Camilla. 

*goto ch2_bath 
*label ch2_bath
A small voice next to me grabs my attention: "I'm kinda cold." I turn to that of a muddied face of Kegan, whose drenched clothes hang pathetically from his lithe frame. By the looks of it, he must've fallen to the ditch — multiple times. Whether by his own clumsiness or someone shoving him in there, I didn't see, but the result is clear.

He clanks his teeth, barely able to mutter the word 'bath?'.

I nod. Floyd hails to us from afar, followed by Brick and Pec. Without much need for small talk and with a stiff walk our small entourage starts its journey towards the bathhouse.

*page_break
Warm marble welcomes my muddy feet as I discard the boots in the changing locker. Perhaps I should thank the Twins for this specific Roman custom, but the thought appears almost blasphemous.

Brick stares at my garment. "Why are you keeping your tunic on?" He himself is displaying his naked skin as if it's a challenge.

Of course he is, a man like him must view modesty as a weakness to abhor. I give him a defying look; I won't take the tunic off, and he will just have to live with that.
    
With the corner of my eye I see Floyd stepping towards us, his features strict, his stance ready for the rising conflict. 

*if brick_friend
    Brick keeps looking at me, but just as I'm about to retort back, he shakes his head. "You know what? It doesn't matter. Dress how you like." He gives me an awkward nod of approval before leaving the changing area.
    
    "That was… unexpected," Floyd says and offers to take my clothes and put them in the same locker. I nod and watch the door where Brick disappeared. Floyd takes a note of our locker (one where an obscene scene of fellatio is depicted) and walks next to me. "He's not usually so easily calmed after he's set his mind into anger."
    
    I suppose I've gained a friend, of sorts.
    
*if not(brick_friend)
    Brick waits for my answer.
    
    *fake_choice
        #"I just don't like to show my skin."
            He scoffs. "You think you're better than us?" My attempt to fuse the situation, or explain myself, is only met with more contempt. There is no talking sense to this wall of a man.
        
            "Brick, stop that," Floyd says.
        
            "Holier than thou, too bashful to show off your pretty princess skin."

            *fake_choice
                #"Shut up, Brick."
                    I stare at him with a the coldest stare I manage. He finally shuts his face and I walk past him with the tunic on.
                #Stay silent and walk past him.        
                    I don't owe any explanations to him or anyone else.
                
                    "Did you just ignore me—"
                
                    "Brick, shut up." Floyd reprimands him with a tired tone.
                #"Drop dead, moron."
                    *set rude +2
                    His mouth hangs open as I walk past him with the tunic on.
                
                    "What the fuck did the little brat say—"
                
                    "Calm down, Brick."
        #"Shut up, Brick."
            I stare at him with a the coldest stare I manage to bring forth. He finally shuts his face and I walk past him with the tunic on.
        #Ignore him and walk past him.
            I don't owe any explanations to him or anyone else.
        
            "Did the brat just ignore me —"
        
            "Brick, shut up." Floyd reprimands him with a tired tone.
        
Kegan's hurried steps echo in the outdoor area, and when he gains up on me, he has an undergarment on as well. An act of comradery? Or imitation? He looks at me and nods.

*fake_choice
    #Smile at him.
        *set kegan_friendship +2
        I give the lad a grateful smile. It's a small gesture, but I can't deny it warms some of the tension off that Brick managed to cause. His face brightens up.
    #Nod at him.
        *set kegan_friendship +2
        He nods again, this time with more vigor and a wider smile. 
    #Shake my head and keep walking.
        He takes a few running steps to keep up with me, unfazed by the lack of response.
    #Ignore him.
        He takes a few running steps to keep up with me, unfazed by the lack of response.

The baths are filled with more men than I'm accustomed to, the chatter littering the damp air like a buzzing of hornets. The hour of the visit is more popular than I'd like to, but I'm too tired and stained to care. We walk right past the cold pool without even taking a glance at it, and continue towards the warm one.

We dip in with little grace. Warmth surrounds me, and finally my muscles relax.

"Are you alright?" Floyd asks, intruding my state of relaxation.

I merely nod, tired of the constant flow of unnecessary interruptions. Let me bathe in peace, I would say to him had I the energy to do so. Floyd reads the lack of response correctly and stays quiet, for now. 

Pec joins us. His grin is gone, in place only a tired smile. Brick doesn't follow him, but changes his direction towards another pool. "Shit if it was a straining day."

There is no need for nods, nor words of confirmation, everyone's tired sighs tell as much.

Floyd starts to clean himself in total disregard of a couple of Legionaries in the same pool giving him dirty looks as we're surrounded by increasingly muddy water. Their bodies are oiled and clean, making me remember the words of Camilla.

We must look like barbarians to them.

*fake_choice
    #"Aren't we supposed to wash in another pool?"
        Floyd stops his scrubbing and gives me a puzzled look before turning beetroot red. "Oh dear. I suppose we are."
        
        "Pools are for bathing," Pec says and starts scrubbing himself in a grandiose manner while looking at the sneering Legionaries.
    #Look at them right in the eye and start washing the biggest stains of mud.
        *set group_friendship +2
        Their eyes widen at the spectacle before their frowns deepen. Pec grins at me and starts to wash himself in a same manner.
        
        One of the Legionaries spits towards us: "Filthy brutes," before beckoning his friend to leave the pool.
        
        "Posh morons," Pec retorts back and winks at me, as if we were accomplices.
    #Ignore them.
        I care little for their social norms. The Legionaries sneer at the oblivious Floyd who's still washing himself without a care in the world. Soon they leave the pool all the while muttering curses at the filthy barbarians.
        
Pec stretches his arms as a loud pop echoes from his joints, followed by a pained frown and a groan: "You think the Optio is a sadist?"

"A bully," Kegan says in a silent voice, reminding me of his existence.

Floyd shakes his head. "Isn't he acting on Centurion's orders? How much of that blame lies on his shoulders?" 

*fake_choice
    #Remain silent.
        A voice interrupts the conversation: "Oh, so you won't defend my honor, soldier?"
    #Bash Marcus some more, he deserves it.
        *set group_friendship +1
        "All of it. I'm sure he knows what his subordinates are doing and he doesn't do anything about it. It's equally his fault, if not more."
        
        Floyd and Pec nod.
        
        Then, a voice interrupts the conversation: "My, my. A pool filled with little wise guys."
    #Defend him. "What if he doesn't know?"
        *set marcus_friendship +1
        The words slip from my lips before I can think any better. Why am I defending him?
        
        Pec frowns. "Then he's a shitty boss."
        
        Floyd raises his brow at me, evidently wondering why I'm so keen on defending him. I really don't know.
        
        Then, a voice interrupts the conversation: "My, my. How kind of you to defend my honor, soldier."
        
An already too familiar baritone voice coated with a heavy layer of sarcasm disturbs the bathing. Everyone in the pool stand up with such a haste, it's as if they didn't just spend the whole day dying on a ditch.

Marcus looms over the pool completely naked with his hands relaxedly on his hips.

*fake_choice
    #Salute him with the rest of men.
    #He looks absolutely ridiculous with his posturing and I let my gaze tell him so.
        I take a brief look at his pelvic area since he's so readily presenting it to everyone to see. I make sure he sees the target of my gaze before turning my attention away from his junk back to his face.
        
        He raises his brow, as if awaiting for my judgment.
        
        I give him a shake of my head. Not impressed.
        
        He furrows his brows before taking a quick glance at his member, as if to make sure we're assessing the same thing. 
        
        I give him a brief nod and continue our voiceless conversation: 'We are. And I still remain unimpressed.'
        
        He gives me a slight frown before shaking his head.
    #Try not to look at him. My eyes keep wandering and I won't let him catch me.
        *set naked_marcus true
        It's not because it's [i]him[/i] who is naked, it's just a daunting situation. Why is he exposing himself like that? There are people with at least a loin-cloth to protect themselves from the eyes of other bathers. He, however, is just flinging his stuff about like it's nobody's business. 
        
        I look at the ground, on the walls, at the ceiling.
        
        "Soldier, are you having a seizure?" The bastard grins as I finally look at him.
        
        "No, Lord Centurion."
        
        "Eyes up front when I'm talking."
        
        I obey, unfortunately now gazing straight at his naked pelvic area.
        
        *fake_choice
            #Heat rises to my cheeks.
                Stupid, stupid treacherous cheeks! I bite my lip to stop it, but it does nothing to halt the warmth circulating the whole of my face.
                
                "Is the water too hot for you, soldier?"
                
                "Yes, Lord Centurion."
                
                "Get out of there, then, you little moron! You look like you might boil alive." The shit-eating grin on his face makes anger rise up to match the embarrassment I'm plagued with.
            #I collect myself and keep my cool.
                *set disciplined +1
                It's just Marcus. All I need to do to is to think what a vile man he is to remember there's nothing to be embarrassed about.
        
"Are you quite done gossiping?"

"Yes, Lord Centurion!"

"Since you still have energy to chatter with such vigor, you will go for a hunt for the evening."

"But it's so late—" Pec starts, but quickly shuts his mouth when Marcus shoots an ugly glare at him.

"Are you disobeying my orders?"

"No, Lord Centurion!"

*page_break
Sun is already setting, we won't have much daylight left. The bath relaxed my frame, but in turn, drowsiness is half-forcing my eyelids shut.

Marcus stands next to me, his gaze to the sky. "It's going to be full moon tonight." He turns back to me. "Have you hunted before?"

I nod. Every high-born child was expected to know how to hunt.
 
*fake_choice
    #I, however, preferred gathering herbs.
        *set herbalist true
        Taking the lives of the animals was never my passion, even if I was expected to do it. I tried to evade any and all hunting trips, but more often than not I was forced to take part in it. 
        *fake_choice
            #I don't even eat animals.
                *set vegetarian true
                *set ruthless -5
                The thought of killing an animal makes me sick to my stomach. Father and his warriors used to mock me for my tendency of imagining a whole life-story for any animal we came across. I couldn't even fish since I was sure they had families waiting for them. It was a running gag, but at least they were somewhat respectful about it.
            #I dislike the act of killing.
                *set ruthless -5
                Even if I don't steer clear from eating animals, I dislike the act of killing. Even the thought of taking another's life makes my stomach turn. Father and his warriors used to mock me for my tendency of imagining a whole life-story for any animal we came across. I couldn't even fish since I was sure they had families waiting for them. It was a running gag, but at least they were somewhat respectful about it.
            #I just prefer gathering plants.
                I don't have anything against hunting itself, I just prefer gathering herbs. It's more like a treasure hunt to look for right plants, than the adrenaline packed endeavor hunting trip is.

        Father and his men treated the animals they killed with respect. The deaths were quick, painless, with much honor given to their ended lives. Father taught me the ways to kill, even if I didn't have a will for it.
        
        Mother mocked my soft tendencies as she clothed and sent me on my way to join Father and his warriors for the hunt.
        
        [i]"You can't live if you don't kill."[/i]
                
        With the words ringing in my ears, I realize that Marcus is gone and I'm staring at Brick's annoyed face.
    #I was a master at hunting.
        *set hunter true
        I was a honorary hunter among Father's warriors after killing a bear at the age of 15.  After that, Father's warriors frequently asked me to accompany them to the hunting trips. 
        
        They taught me the ways of the hunt, to treat the animals with respect, to grant every one of them a quick death as painlessly as possible. 
        
        They give their life so we may live.
        *fake_choice
            #I've never had any problem with killing.
                I grew accustomed to the idea, and the deed, of deciding between someone's life and death, its heavy consequences, and the fact that every time I ensured my own survival.
            #I dislike killing, but sometimes it's necessary.
                I've never taken pleasure of taking another's life. I don't think it's something to enjoy, even if hunting trips themselves were enjoyable. It was a good opportunity to spend time together with Father and his men, it meant a lot of camping and stories round the fireplace.
                
        As I come back from my reminiscing, Marcus is already gone and I realize I'm staring at Brick's annoyed face.

"I asked: You know how to hold a bow?"

*if build = "lithe"
    "I prefer slings."
    
    *if brick_friend
        He gives me a slow, deliberate nod, eyeing me up and down. "These can be deadly, too, if you know how to use them. You look like you can."
        
        "Thank you?"
        
        He nods again before giving me a sling and a bag of lead bullets. He continues, frowning as if the words make him physically ill: "Hope we have a good hunt."
        
        I nod, puzzled over his act of friendliness. He seems equally puzzled over his own self and he leaves quickly with a deep frown, his friendly words still lingering behind. 
    *if not(brick_friend)
        "Figured. You look like the wind might take you."
    
        "Excuse me?"
    
        "You 'eard me." He says as he shoves me a sling and a bag of lead bullets. He doesn't even stay to listen if I have anything to add, he just leaves. 
    
*if ((build = "average") or (build = "heavy"))
    "Yes."
    
    *if brick_friend
        He looks me up and down. "Good for you. Put it to good use." He gives me bow with a solemn nod. He continues, and the words look like they make him physically ill: "Hope we have a good hunt."
        
        I nod, puzzled over his act of friendliness. He seems equally puzzled over his own self and he leaves quickly with a deep frown, his friendly words still lingering behind. 

    *if not(brick_friend)
        "Hm." He sounds less than convinced but still hands me a composite bow. He doesn't even stay to listen if I have anything to add, he just leaves. 
        
The tired chatter of Pec and the others sounds muffled to my ears. Kegan gawks at them a little farther away, his mouth pursed. No one seems interested in the trip.

I need to say a quick prayer to the Twins. "Thank you for granting me a gift of a flesh not my own. I beg for you to take care of the soul who lost its home. Another dies so I may live, and I will do so with gratitude," I whisper the words in a quick, accustomed succession. The language is my own and a surge of warmth spreads through my chest as the prayer departs from my lips.  

"Who was it that you begged forgiveness of?" Marcus's voice.

I stifle the urge to shout. How did he know what I was saying? I squint my eyes ate him, as if it would urge him to tell me how he knows my language and why feels it's his right to listen in to my private moment. But of course he remains silent. He merely gives me a wide grin, expecting an answer for his question. 

"…Diana," I say. A Roman goddess of hunt might be a safer bet to claim praying to in these circumstances. Even if the lie feels futile, he seems to know much more than he lets on.

"Oh, really." The other corner of his lips rises, forming an all too familiar smirk.

*fake_choice
    #He's annoying. Talk back at him.
        *set rude +1
        *set disciplined -1
        "Yes. Really. What are you doing here, anyway? [i]Lord Centurion[/i]." Annoyance coats my words, and it only feeds the Centurion's sneer.
    #It's better to act civil. At least it would make one of us.
        *set rude -1
        *set disciplined +1
        "Yes, Lord Centurion." I clench my jaw and keep my annoyance at bay. "What is that you wanted from me, Lord Centurion?"

He readily ignores my question and continues: "Have you abandoned your own gods, Hati? Was your faith so fleeting?" 

*fake_choice
    #"That is none of your concern."
        I say with a steady tone, giving him no other reaction. He gives me a small pout and just as he's about to continue his harassment, someone clears their throat.
    #"I don't wish to talk about this, Lord Centurion."
        *set rude -1
        *set disciplined +1
        "Ugh. What a bore you are." He gives me a small pout and just as he's about to continue his harassment, someone clears their throat.
    #How dares he?!
        *set disciplined -2
        A sudden burst of anger flows through my body. "How dare you to suggest I'd abandon my gods?!"
        
        As expected, Marcus's smile widens at my outburst. "I didn't know the subject was so touchy to you."
        
        As if he didn't. Just as my fingers curl into a tight fist, someone clearing their throat interrupts the situation.
    #"I see your gods the same as mine. Isn't that what you Romans preach?"
        I give him a small, seemingly innocent smile accompanying the statement. Foreign gods are usually seen by the Romans as their gods, but with a different name.
        
        He squints his eyes with delight and nods. "Why, indeed it is. What a sharp little moron you are."
        
        Someone clearing their throat stops the conversation.

Quinn.

"Am I interrupting?" $!{q_he} aims ${q_his} words at Marcus.

Marcus merely glances at ${q_him}, annoyance clearly visible in his features, and turns back to me. "As to your question, I am of course coming with you."

Just now I realize Marcus has a dog with him, a sturdy and calm beast. Marcus smiles at the dog. "Robus comes, too. She needs exercise."

She's been sitting further away from us with no sound, examining our conversation. 

Robus lets out a conversational 'woo woo' once, as if to agree with the statement. She's clearly a hunting dog, meant for killing big preys. But the loving way she looks at Marcus implies she also likes to take naps on his human's lap. Her shiny black fur is groomed well, it looks soft to the touch.

*fake_choice
    #Pet her.
        *set robus_friendship +1
        Without much thought I bend down to invite her for greeting cuddles. It's time to test if the fur is indeed as soft as it looks. "Come here, girl!"
        
        She gives Marcus a side-glance, not sure if she should accept the invitation. Marcus gives her a nod and she starts lazily jogging to me while wagging her tail. She presses her side heavily against my shins, waiting for the promised pets. Her soft hair against my skin makes me smile.
        
        "Such a good dog," I say, mostly to myself when she finally leaves my side. 
        
        Marcus nods, giving her a pat on her side. "She is."
    #Remain silent.

Marcus turn his attention to Quinn. He makes a show of looking down his nose at ${q_him}, as if ${q_he}'s merely a bug to be stomped under his boot. He doesn't even ask ${q_him} anything, he just seemingly wishes the intruder would leave.

Quinn, totally unfazed by the display, gives him a bright smile. It doesn't reach ${q_his} eyes but looks genuine enough. "I'm supposed to help you with the equipment. As per Lord Tribune's orders."

Niall? Why would he tell Quinn to join us?

Marcus purses his lips and promptly ignores the fact that Quinn didn't call him by his title. Then, as he's left without any other option, he leaves with Robus on his heels.

"Why did Lord Tribune ask you to join us?"

"Hm, I wonder." $!{q_he} smiles. "Come now, let the hunt begin!"

*page_break
The last dying rays of the late autumn sun shine through the multicolored leaves as I peer behind of the leaving men. They're supposed to circle the area and catch any prey we might miss. Quinn and I are left alone with Marcus.

As the sunlight barely has the strength to warm the tips of my cheeks and dried up leaves rustle under our entourage's boots, we're following our hunting dog. Robus's demeanor shifted quickly into a work-mode: her muzzle is glued to the ground, her step quicker than her sturdy frame would suggest.

It's already past the symphony of the birds, even of those who like to serenade late in the evening. 

It's silent.

*page_break
A peek of a blood-red moon comes to view after the last rays of sunlight die. It does little to illuminate the forest.

As the tips of my fingers slowly start losing their feeling due to frigidness of the air, my gaze lies on Marcus's back. His steps are quick and silent, his movement nimble. He's experienced in the woods. His sword dangles on his hip.

A thought pops into my mind without my will: He's left surprisingly defenseless.

*if hatred = "manipulated"
    [i]Kill him.[/i] 
    
    The voice.
    
    I glance at Quinn, but ${q_he} keeps walking as if nothing happened. Of course ${q_he} would, the thing is inside my head. 
    
    Does the voice want me to kill Marcus… now?
    
    Then, it shrieks again, this time with more malice: [b][i]Kill him![/i][/b]
       
    *fake_choice
        #"Leave me alone!"
            I howl at the voice, shielding my ears. It's useless, of course, I can't block it but I have to try something.
            
            "Are you alright?" Quinn's voice. $!{q_his} concerned gaze makes me realize I shouted the words out loud.
            
            Marcus has turned to me, too. My outburst caused his frame to tense, his eyes inspecting me.
            
            *if marcus_voices
                "Are you… feeling alright?" He echoes Quinn's sentiment, both of them peering into me, assessing if I will lose my mind sooner rather than later.
                
                "Yes, Lord Centurion."
                
                He doesn't look convinced and I can't exactly blame him. He knows I hear voices, and now I'm shouting at myself. Throwing a last doubting gaze he turns away.
            *if not(marcus_voices)
                "Are you trying to drive the prey away, soldier?"
                
                "No, Lord Centurion."
                
                "Whether you're trying or not, you're doing it. Stop it."
                
                "Yes, Lord Centurion." I take a deep breath to try and stabilize my state. Marcus gives me a last doubting gaze before turning away.
                
        #"I can't do it!"
            I yell at it. I can't kill him. Not here. Not now. 
            
            The worst thing is… I don't know if I can kill him at all.
            
            "Are you alright?" Quinn's voice. $!{q_his} gaze is concerned, making me realize I shouted the words out loud.
            
            Marcus has turned to me, too. My outburst caused his frame to tense, his eyes inspecting me.
            
            *if marcus_voices
                "Are you… feeling alright?" He echoes Quinn's sentiment, both of them peering into me, assessing if I will lose my mind sooner rather than later.
                
                "Yes, Lord Centurion."
                
                He doesn't look convinced and I can't exactly blame him. He knows I hear voices, now I'm shouting at myself. Throwing a last doubting gaze he turns away.
            *if not(marcus_voices)
                "Are you trying to drive the prey away, soldier?"
                
                "No, Lord Centurion."
                
                "Whether you're trying or not, you're doing it. Stop it."
                
                "Yes, Lord Centurion." I take a deep breath to try and stabilize my state. Throwing a last doubting gaze Marcus turns away.
        #Close my eyes and try to ignore it.
            *set disciplined +1
            The shriek continues to shake my core, but I ignore it. At least I know now what it wants from me.
            
            "Are you alright?" Quinn asks. Just now I realize that I've stopped walking. 
            
            "Yes," I say. The reassurance is more to myself than to ${q_him}. I take a deep breath, and another. The voice went away.
    
*if hatred = "determined" 
    I could kill him.

    “We could kill him.” Quinn's whisper touches the lobe of my ear, emphasizing my own thoughts.

    His back is turned to us. Conveniently. Too conveniently. Is he baiting us?

    *if build = "lithe"
        My sling weighs heavy on my hip.
    
    *if ((build = "average") or (build = "heavy")) 
        My bow weighs heavy on my back. 
    
    I can't beat him in a sword fight, but I could shoot him. Could I?

    *fake_choice
        #No. It's not the right time.
            How could I kill him here? Everyone would know it was me. I would need to run. "It's better to wait," I say and Quinn nods.
        #I... can't.
            *set ch2_marcuskiller_nope true
            The skin on the palm of my hand shivers, as if afraid I'd command it to do the deed. Disappointment washes over me. Why can't I bear the thought of killing him? Isn't that what I wanted?
                
            What am I doing here, if I can't kill him? He's the one who killed my father, he's one of the reasons why I'm here.
                
            Yet the thought twists my stomach.
                
            Just now I realize Quinn's eyes on me. $!{q_his} expression is unreadable before ${q_he} nods with a solemn expression. "We need to wait."
        #Yes. I will do it.
            *set robus_friendship -1
            *set marcus_killer true
            Cold determination fills me as a wave of autumn breeze tries to penetrate my clothes, cooling my whole body. It needs to be done. All I see is the back of his head, where I need to hit. My hand reaches for my
            *if build = "lithe"
                sling.
            *if ((build = "average") or (build = "heavy"))
                bow.
                
            Then. 
            
            A growl.
            
            I look down and meet the murderous gaze of Robus. She smelled my intention. Her eyes are locked on to me, daring me to act. To give her a reason to attack and tear my throat open.
            
            Marcus turns to us. "What are you doing?" 
            
            Robus growls one more time before disappearing back to her tracking duties. Marcus peers into my soul, his gaze hard.
            
            This was stupid.
            
    "Perhaps you should lead our merry group," Marcus says, his tone light and amused. It would fool me if his eyes weren't cold. He knows what I was about to do.
    
    He always knows.

*page_break
We follow Robus's controlled barks.
    
A stag.

The young stag has gotten used to the barks, not giving them much heed. He keeps feeding on the grass, unknowing of anything amiss.

Oh. No.

Not the stag.

Quinn's widened eyes look at me when I turn to ${q_him}.

"We can't just kill—" $!{q_he} starts to say but is interrupted by Marcus:
    
"Kill it."

Why did it have to be a stag? The Twins won't allow this. They will strike me dead if I kill him.

Marcus frowns at my hesitation. "What are you waiting for, you little moron? Just kill it."

I can't, I almost shout. The Twins. They don't allow the killing of stags. The stag is sacred. "I—"

He waits for me to act, not to speak. 

*fake_choice
    #I have to do it. If I don't kill the stag, Marcus will kill me.
        *set romanization +1
        I gulp and steel myself for what's to come. The Twins will kill me for this. Either that, or they will plague me with diseases until I finally drop dead. 
        
        At least I have some time before that happens. If I don't kill the stag, I will die in the spot.
        
        As I start to slowly nod, a voice interrupts me: "No. You won't kill the stag."
        
        Quinn. 
    #I can't. I won't. I have to prepare myself for the consequences.
        *set romanization -1
        I gulp and steel myself for what's to come. I will disobey an order. He will either have me flogged, or he will kill me on the spot.
        
        Which one will he choose?
        
        At least I will die with my dignity. This is who I am. I am the last druid of the Twins.
        
        "Lord Centurion, I—"
        
        Then, a voice interrupts me: "No. You won't kill the stag."
        
        Quinn. 

*page_break
My blood turns to ice as I peer behind me: Marcus's eyes are glued into Quinn, ${q_his} stare mere murder. Quinn dared to defy a direct order: it's grounds for execution. However, he gives ${q_him} a chance to take it all back: "Did you say something? Did you, by any chance, defy a direct order?"

It's a sudden act of mercy. Take it. 

However, ${q_he} doesn't. $!{q_he} stares Marcus, a small smile tugging the corner of ${q_his} mouth.

Marcus, growing increasingly annoyed, his jaw tightened, asks again: "Did I hear you correctly?" 

Finally Quinn answers: "If you heard me saying no."

"You dare—"

*fake_choice
    #"Lord Centurion, it must've been a mistake."
        "A mistake? $!{q_he} disobeyed me by mistake?"
        
        Quinn ignores my attempts of diffusing the situation. "It was no mistake, you pathetic little man." $!{q_his} smile is now fully taken over ${q_his} features. It's a cruel one, mocking. "${name}." $!{q_he} turns ${q_his} attention briefly to me, using my real name. "Back off."
    #"Quinn, back off."
        I hiss at ${q_him} but ${q_he} doesn't even turn to look at me. Is ${q_he} trying to get ${q_him}self killed?
        
        "Why don't you tell that pathetic little man to back off, ${name}? Are you on his side?"
    #Remain silent and watch how the scene unfolds.
        Quinn's smile is now fully taken over ${q_his} features. It's a cruel one, mocking. "You pathetic little man." $!{q_he} turns ${q_his} attention briefly to me. "${name}, good of you to stay back. Let me handle this."
        
Marcus squints his eyes. "You're not even trying to hide ${xis} identity? You're using ${xis} real name now?"

Quinn shrugs. "You already now. And yet you still choose to let ${xim} live. Why?"  Then ${q_his} eyes squint into mere slits as the corners of ${q_his} mouth rise. "Disgraceful. You're preying on your subordinates. Is that what you're doing, you dirty old man?"

The corners of Marcus's eyes twitch as the veins on his neck become more visible. "What did you say, you little—"
        
"Are you having hard time hearing? Should you consider retiring? In your [i]age[/i]."
        
Cold washes over me as I watch the unfolding scene. $!{q_he}'s dead.
        
Marcus unsheathes his sword without words. He needs none. His intention is clear.
        
"No—," I say, too quiet, too slow, no words can help now. 

*fake_choice
    #I need to protect ${q_him}. I need to save Quinn.
        I take my sword, what else can I do. Marcus hears the sound of the unsheathing.
        
        "What are you doing, little witch? Are you disobeying my orders, too?"
        
        Just as I'm about to answer him, his arm falls limp. The sword hits the ground with a muted thump. With furrowed brows he looks at the arm, as if wondering what happened.
    #"Marcus, stop it!"
        *set marcus_friendship +1
        I yell at the man. He turns to me, lowering his sword. The intention of killing is still clearly visible, but it's coated with puzzlement. 
        
        "Marcus?" He asks, as if to confirm he heard his given name to leave my lips. "I'm Marcus to you?"
        
        Quinn sneers behind the man. "Don't you dare to turn your back on me."
        
        Marcus's eyes still hold mine, but there's a muted thump. We both look at the sword that's now lying on the ground. His arm is completely limp and with furrowed brows he looks at it, as if wondering what happened.
    #There's nothing I can do!
        With my eyes widened there's nothing to do but to watch. Bleak, reddish moonlight shines from the surface of the blade, the same blade that killed my father.
        
        Now it will kill Quinn.
        
        I squint my eyes shut, keep them tightly closed and hope for a miracle. 
        
        However, nothing happens. I open my eyes to see Marcus, his sword raised and ready for the killing blow he won't deliver. Instead, there's a muted thud as the sword on his hand falls to the ground. His arm is completely limp and with furrowed brows he looks at the arm, as if wondering what happened.

What?
*page_break

Blood begins to drip from Marcus's nostril. He doesn't seem to notice it, doesn't wipe it clean. The redness flows free to the corner of his mouth, continuing its path to his neck. 

"Lord Centurion?" I ask, but there's no answer. The only sound is the wind rustling the dying leaves.

Without answering, or even blinking, he turns on his heels and starts walking away in a lethargic pace. He stumbles on a root, barely keeping his stance. Robus whines and takes off after him, trying to get her human's hand to pet him. However, his hands remain lifeless. 

He just keeps walking like he's… dead.

The only thing shining in the by-now dark forest is the abandoned sword on the ground, even the useless moon is covered behind the clouds.

"Quinn? What's happening?" I turn to ${q_him}, but ${q_he} doesn't answer. $!{q_he} just…

Smiles. 

"Do you want a cookie?"

Then, darkness engulfs me.

*page_break
Quinn's face is the first thing I see. I quickly get up to get my bearings. I'm on the border of the forest, Floyd and Kegan are peering at me from the distance with troubled expressions. The moon has glided across the horizon; it's extremely late.

"Why am I here? What happened?"

"You passed out." Quinn's voice is coated with worry as ${q_he} peers at me.

Why is ${q_he} worried for me? $!{q_he}'s the one who almost got killed. "What about Marcus?"

"What about him?"

"What?" What does ${q_he} mean? Of course I mean the almost murder that took place in the forest, how Marcus wandered off without a word, how—

"Soldier, are you going to faint on me again?" A familiar mocking voice reaches my puzzled state, causing even more of a turmoil within me. Marcus. The light of his torch dances on his features, giving away no sign of worry, peril, nor murderous intent. Nothing. Just a sense of distrust over… me?

How am I the problem here?

"Aren't you going to answer me?"

*fake_choice
    #"Are you feeling alright, Lord Centurion?" Where's the blood on his face?
        *set marcus_friendship +1
        "Am I feeling alright?" He repeats the question, scrutinizing me as if I asked something stupid.
        
        "Blood came from your nose and—"
        
        "Aww, did you have a little nightmare about me?" His features burst into a wide grin. "I'm touched that you worry about me in your dreams."
        
        "What? No. You were—"
        
        "Now, now, soldier. I'm quite alright, you must still be dizzy from your horrendous nightmares about little old me.
    #"Aren't you going to kill Quinn?" What is happening here?
        "Kill your little friend? Why would I want to kill ${q_him}?"
        
        Why? But… He was ready to kill ${q_him} just recently. What happened? 
        
        He grins. "Do you want me to kill ${q_him}?"
        
        "No!"
        
        "Did you have a little nightmare, soldier? Are you still dizzy?
    #"No, Lord Centurion." It's better to play along now. Why does everyone keep acting like nothing happened?
        "Good. You look like you're still dizzy.
You fainted as you were taking the kill shot. Didn't take you for a wimp, but here we are." He sighs. "The deer ran away, and we had to carry you here with your little friend."

"Carry your stuff back to the fort, soldier. I'm done babysitting you." With these words he leaves, his cloak billowing behind him in the moonlight. The spring of life in his step is back, gone is the way the dead would walk.

Quinn's still staring at me when I turn back to ${q_him}. "What happened?"

*fake_choice
    #Tell ${q_him} what happened.
        "You shouted so I missed the shot and the deer ran away. Marcus was going to kill you for it. But suddenly his nose started to bleed and he left and—" As the words flow freely from my mouth, Quinn's expression change from worried to extremely worried.
        
        "$!{name}… None of that stuff happened. It's as he said, you fainted as you were going for the kill shot. The deer ran away. We had to carry you."
        
        "I—," I start, but there's nothing I can say.
        
        "Are you… feeling alright?"
        
        I nod, slowly, trying to convince both ${q_him} and myself.
    #Ask what happened.
        "What… happened?" Evidently not what I saw, it seem. How is that possible?
        
        "It's as he said, you fainted as you were going for the kill shot. The deer ran away. We had to carry you."
        
        I nod, processing the information.
        
        "$!{name}. Are you sure you're feeling alright?"
        
        I nod, slowly, trying to convince both ${q_him} and myself.
    #It's better to keep this to myself. I don't want to seem crazy.
        Quinn peers at me, ${q_his} gaze worried. "Are you sure you're alright?"
        
        I nod, slowly, trying to convince both ${q_him} and myself.
    #"Yes. I think I had a dream." What else could it be? 
        I nod, slowly, trying to convince both ${q_him} and myself. What else could've happened? It just felt so real…

There are now two people claiming nothing happened, that I was seeing things. Was it a dream? Is it connected to the voice in my head?

As the wind caresses my skin with its freezing touch, a wave of shivers run through my body. 

Am I going insane?
*page_break
*goto_scene chapter_3